plugins {
    id "com.android.application"
    // START: FlutterFire Configuration
    id 'com.google.gms.google-services'
    // END: FlutterFire Configuration
    id "kotlin-android"
    id "dev.flutter.flutter-gradle-plugin"
}


def getVersionCode = { ->
    "git rev-list --count HEAD"
            .execute()
            .text.trim()
            .toInteger()
}

android {
    namespace 'com.comwell.phoenix'
    compileSdkVersion 36
    ndkVersion "28.2.13676358" //flutter.ndkVersion
    flavorDimensions += "env"

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    } 

    kotlinOptions {
        jvmTarget = '17'
    }

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
    }

    defaultConfig {
        println 'flutter.minSdkVersion='+flutter.minSdkVersion
        applicationId "com.comwell.phoenix"
        minSdkVersion 28
        targetSdkVersion 36
        versionCode getVersionCode()
        versionName flutter.versionName
        multiDexEnabled true
        manifestPlaceholders += [
            'appAuthRedirectScheme': 'comwellservicesdev.b2clogin.com'
        ]
    }

    signingConfigs {
        release {
            def keystoreProperties = new Properties()
            def keystorePropertiesFile = rootProject.file('key.properties')
            if (keystorePropertiesFile.exists()) {
                keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
            }
            storeFile rootProject.file("comwell_keystore.jks")
            storePassword keystoreProperties['storePassword']
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
        }
        debug {
            
        }
    }
    buildTypes {
        release {
            println(getVersionCode())
            signingConfig signingConfigs.release
            minifyEnabled false
            shrinkResources false
        }
        debug {
            signingConfig signingConfigs.debug
            minifyEnabled false
            shrinkResources false
        }
    }


    productFlavors{
        Develop {
            dimension = "env"
            resValue "string", "app_name", "Comwell Phoenix Dev"
            applicationIdSuffix = ".dev"
        }
        Stage {
            dimension = "env"
            resValue "string", "app_name", "Comwell Phoenix Stage"
            applicationIdSuffix = ".stage"
        }
        Prod {
            dimension = "env"
            resValue "string", "app_name", "Comwell Phoenix"
        }
    }
}

flutter {
    source '../..'
}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    //aar file from libs dir. Name and version is from the filename.
    debugImplementation fileTree(dir: '../../..//mobilekeys_sdk_plugin/android/libs', include: ['mobilekeys-android-sdk-debug-*.aar'])
    releaseImplementation fileTree(dir: '../../..//mobilekeys_sdk_plugin/android/libs', include: ['mobilekeys-android-sdk-release-*.aar'])
}